home *** CD-ROM | disk | FTP | other *** search
/ X User Tools / X User Tools (O'Reilly and Associates)(1994).ISO / sun4c / archive / tcltk.z / tcltk / slib / tk / demos / mkSearch.tcl < prev    next >
Text File  |  1994-09-20  |  5KB  |  141 lines
  1. # mkTextSearch w
  2. #
  3. # Create a top-level window containing a text widget that allows you
  4. # to load a file and highlight all instances of a given string.
  5. #
  6. # Arguments:
  7. #    w -    Name to use for new top-level window.
  8.  
  9. proc mkTextSearch {{w .search}} {
  10.     catch {destroy $w}
  11.     toplevel $w
  12.     dpos $w
  13.     wm title $w "Text Demonstration - Search and Highlight"
  14.     wm iconname $w "Text Search"
  15.  
  16.     frame $w.file
  17.     label $w.file.label -text "File name:" -width 13 -anchor w
  18.     entry $w.file.entry -width 40 -relief sunken -bd 2 -textvariable fileName
  19.     button $w.file.button -text "Load File" \
  20.         -command "TextLoadFile $w.t \$fileName"
  21.     pack $w.file.label $w.file.entry -side left
  22.     pack $w.file.button -side left -pady 5 -padx 10
  23.     bind $w.file.entry <Return> "
  24.     TextLoadFile $w.t \$fileName
  25.     focus $w.string.entry
  26.     "
  27.  
  28.     frame $w.string
  29.     label $w.string.label -text "Search string:" -width 13 -anchor w
  30.     entry $w.string.entry -width 40 -relief sunken -bd 2 \
  31.         -textvariable searchString
  32.     button $w.string.button -text "Highlight" \
  33.         -command "TextSearch $w.t \$searchString search"
  34.     pack $w.string.label $w.string.entry -side left
  35.     pack $w.string.button -side left -pady 5 -padx 10
  36.     bind $w.string.entry <Return> "TextSearch $w.t \$searchString search"
  37.  
  38.     button $w.ok -text OK -command "destroy $w"
  39.     text $w.t -relief raised -bd 2 -yscrollcommand "$w.s set" -setgrid true
  40.     scrollbar $w.s -relief flat -command "$w.t yview"
  41.     pack $w.file $w.string -side top -fill x
  42.     pack $w.ok -side bottom -fill x
  43.     pack $w.s -side right -fill y
  44.     pack $w.t -expand yes -fill both
  45.  
  46.     # Set up display styles for text highlighting.
  47.  
  48.     if {[tk colormodel $w] == "color"} {
  49.     TextToggle "$w.t tag configure search -background \
  50.         SeaGreen4 -foreground white" 800 "$w.t tag configure \
  51.         search -background {} -foreground {}" 200
  52.     } else {
  53.     TextToggle "$w.t tag configure search -background \
  54.         black -foreground white" 800 "$w.t tag configure \
  55.         search -background {} -foreground {}" 200
  56.     }
  57.     $w.t insert 0.0 {\
  58. This window demonstrates how to use the tagging facilities in text
  59. widgets to implement a searching mechanism.  First, type a file name
  60. in the top entry, then type <Return> or click on "Load File".  Then
  61. type a string in the lower entry and type <Return> or click on
  62. "Load File".  This will cause all of the instances of the string to
  63. be tagged with the tag "search", and it will arrange for the tag's
  64. display attributes to change to make all of the strings blink.
  65. }
  66.     $w.t mark set insert 0.0
  67.     bind $w <Any-Enter> "focus $w.file.entry"
  68. }
  69. set fileName ""
  70. set searchString ""
  71.  
  72. # The utility procedure below loads a file into a text widget,
  73. # discarding the previous contents of the widget. Tags for the
  74. # old widget are not affected, however.
  75. # Arguments:
  76. #
  77. # w -        The window into which to load the file.  Must be a
  78. #        text widget.
  79. # file -    The name of the file to load.  Must be readable.
  80.  
  81. proc TextLoadFile {w file} {
  82.     set f [open $file]
  83.     $w delete 1.0 end
  84.     while {![eof $f]} {
  85.     $w insert end [read $f 10000]
  86.     }
  87.     close $f
  88. }
  89.  
  90. # The utility procedure below searches for all instances of a
  91. # given string in a text widget and applies a given tag to each
  92. # instance found.
  93. # Arguments:
  94. #
  95. # w -        The window in which to search.  Must be a text widget.
  96. # string -    The string to search for.  The search is done using
  97. #        exact matching only;  no special characters.
  98. # tag -        Tag to apply to each instance of a matching string.
  99.  
  100. proc TextSearch {w string tag} {
  101.     $w tag remove search 0.0 end
  102.     scan [$w index end] %d numLines
  103.     set l [string length $string]
  104.     for {set i 1} {$i <= $numLines} {incr i} {
  105.     if {[string first $string [$w get $i.0 $i.1000]] == -1} {
  106.         continue
  107.     }
  108.     set line [$w get $i.0 $i.1000]
  109.     set offset 0
  110.     while 1 {
  111.         set index [string first $string $line]
  112.         if {$index < 0} {
  113.         break
  114.         }
  115.         incr offset $index
  116.         $w tag add $tag $i.[expr $offset] $i.[expr $offset+$l]
  117.         incr offset $l
  118.         set line [string range $line [expr $index+$l] 1000]
  119.     }
  120.     }
  121. }
  122.  
  123. # The procedure below is invoked repeatedly to invoke two commands
  124. # at periodic intervals.  It normally reschedules itself after each
  125. # execution but if an error occurs (e.g. because the window was
  126. # deleted) then it doesn't reschedule itself.
  127. # Arguments:
  128. #
  129. # cmd1 -    Command to execute when procedure is called.
  130. # sleep1 -    Ms to sleep after executing cmd1 before executing cmd2.
  131. # cmd2 -    Command to execute in the *next* invocation of this
  132. #        procedure.
  133. # sleep2 -    Ms to sleep after executing cmd2 before executing cmd1 again.
  134.  
  135. proc TextToggle {cmd1 sleep1 cmd2 sleep2} {
  136.     catch {
  137.     eval $cmd1
  138.     after $sleep1 [list TextToggle $cmd2 $sleep2 $cmd1 $sleep1]
  139.     }
  140. }
  141.